/* seasons.pov
 */

#macro season(s,dTheme,bTheme)
  #local RAD = 0.5;
  #local DOTRAD = .08;
  #local WIDTH  = .023;
  #local r = RAD - DOTRAD;
  merge {
    #if (s = 4)
      sphere { < 0.400, 0.115,0> DOTRAD texture{dTheme} }
      sphere { < 0.230,-0.290,0> DOTRAD texture{dTheme} }
      sphere { <-0.420,-0.100,0> DOTRAD texture{dTheme} }
      sphere { < 0.000, 0.450,0> DOTRAD texture{dTheme} }
      sphere { <-0.045,-0.070,0> DOTRAD texture{dTheme} }
    #else
      #local i = 0;
      #while (i < 5)
        #local p0 = <cos(radians((i  )*72+90))*r,sin(radians((i  )*72+90))*r,0>;
        #local p1 = <cos(radians((i+1)*72+90))*r,sin(radians((i+1)*72+90))*r,0>;
        #local p2 = <cos(radians((i+2)*72+90))*r,sin(radians((i+2)*72+90))*r,0>;
        sphere { p0 DOTRAD texture{dTheme} }
        #if (s = 1 | s = 2) cylinder { p0 p2 WIDTH texture{bTheme} } #end
        #if (s = 2 | s = 3) cylinder { p0 p1 WIDTH texture{bTheme} } #end
        #local i = i + 1;
      #end
    #end
  }
#end

/**/

#include "colors.inc"
#include "metals.inc"

camera {
  orthographic
  direction <0, 0, 1>
  location <0, 0.2, -3>
  up <0, 3*1, 0>
  right <3*image_width/image_height, 0, 0>
  look_at <0, 0.2, 0>
}
light_source { < 9,  9, -20> color rgb <1.0,1.0,1.0> }
light_source { <-9,  9, -20> color rgb <0.3,0.3,0.3> shadowless }
light_source { <-9, -9, -20> color rgb <0.3,0.3,0.3> shadowless }
light_source { < 9, -9, -20> color rgb <0.3,0.3,0.3> shadowless }

#local i = 0;
#while (i < 5)
  object {
    season(i,texture{T_Silver_3B},texture{T_Brass_3B})
    translate <cos(radians(i*72+90)),sin(radians(i*72+90)),0>
  }
  #local i = i + 1;
#end

/**/