/* psychohazard.pov
 */

#declare psychohazard = intersection {
  #local RAD  = 0.299;   //from center to center of pentagon
  #local RAD1 = 0.25;    //pentagon radius
  #local RAD2 = 0.205;   //pentagon cutout radius
  #local CUT  = 0.26975; //radius of cutout peak
  merge {
    #local i=0;
    #while (i<(72*5))
      difference {
        prism { -2, 2, 6,
          #local j=0;
          #while (j<(72*6))
            <cos(radians(j))*RAD1,sin(radians(j))*RAD1>
            #local j=j+72;
          #end
        }
        prism { -2, 2, 6,
          <CUT,0>
          #local j=72;
          #while (j<(72*5))
            <cos(radians(j))*RAD2,sin(radians(j))*RAD2>
            #local j=j+72;
          #end
          <CUT,0>
        }
        rotate <0,-i,0>
        translate <cos(radians(i))*RAD,0,sin(radians(i))*RAD>
      }
      #local i=i+72;
    #end
    rotate <0,-90,0>
  }
  //this prevents some artifacting from merge
  box { <-2,-1,-2> <2,1,2> }
};

/**/

#include "colors.inc"
#include "stones.inc"
#include "textures.inc"

camera {
  direction <0, 0, 1>
  location <0, 2.0, 0.015>
  up <0, 1, 0>
  right <image_width/image_height, 0, 0>
  look_at <0, 0, 0.015>
}
light_source { < 15, 20, -15> color rgb <1.0,1.0,1.0> }
light_source { <-15, 20, -15> color rgb <0.5,0.5,0.5> shadowless }
light_source { < 15, 20,  15> color rgb <0.5,0.5,0.5> shadowless }
light_source { <-15, 20,  15> color rgb <0.5,0.5,0.5> shadowless }

object {
  psychohazard
  texture { T_Stone3 scale .02 }
//  texture { Sapphire_Agate }
}

/**/