/* page51.pov
 */

#macro page51(texBase,texTrim,texDetail,texRing,texFive)
  #local basey = 10;
  #local hidey = 50;
  #local facey = 100;
  #local trimy = 120;
  #local tt = <sin(radians(234))*526,0,-cos(radians(234))*526>;

  #macro tobez(pt1,pt2)
    pt1
    <pt1.x+((pt2.x-pt1.x)/3),pt1.y+((pt2.y-pt1.y)/3)>
    <pt2.x-((pt2.x-pt1.x)/3),pt2.y-((pt2.y-pt1.y)/3)>
    pt2
  #end
  #macro ring(xx,yy,rr)
    difference {
      cylinder { <xx,hidey-5,yy> <xx,trimy+5,yy> rr+5 }
      cylinder { <xx,hidey-5,yy> <xx,trimy+5,yy> rr-5 }
    }
  #end
  #macro pentpoints(rad,offs)
    #local i=0;
    #while (i<6)
      <cos(radians(i*72+offs))*rad,sin(radians(i*72+offs))*rad>
      #local i=i+1;
    #end
  #end

  merge {
    //base
    prism { basey, facey, 6, pentpoints(520,90) texture { texBase } }
    //end base

    //trim
    intersection {
      merge {
        prism { -5, trimy+5, 12, pentpoints(526,90) pentpoints(500.5,90) }
        #local i=0;
        #while (i<5)
          box { <17,hidey,3> <647,trimy+5,-17> translate tt rotate <0,i*72+126,0> }
          #local i=i+1;
        #end
      }
      cylinder { <0,0,0> <0,trimy,0> 527 }
      texture { texTrim }
    }
    //end trim

    //triangle/circle detail
    intersection {
      merge {
        #local i=0;
        #while (i<5)
          merge {
            prism { hidey-5, trimy+5, 8,
              <50,-47> <50,-357.673> <150.944,-47> <50,-47>
              <40,-37> <40,-420.811> <164.708,-37> <40,-37>
            }
            ring(92.478, -89.478, 47.478)
            ring(78.7564, -176.112, 33.7564)
            ring(68.7871, -239.056, 23.7871)
            ring(61.544, -284.787, 16.544)
            ring(56.2816, -318.013, 11.2816)
            translate tt rotate <0,i*72+126,0>
          }
          #local i=i+1;
        #end
      }
      cylinder { <0,hidey,0> <0,trimy,0> 527 }
      texture { texDetail }
    }
    //end detail

    //inner ring
    intersection {
      merge {
        prism { hidey-5, trimy+5, 12, pentpoints(310,0) pentpoints(260,0) }
        #local i=0;
        #while (i<5)
          #local d2=radians(i*72);
          cylinder {
            <cos(d2)*260,hidey-5,sin(d2)*260>
            <cos(d2)*260,trimy+5,sin(d2)*260> 35
          }
          #local i=i+1;
        #end
      }
      cylinder { <0,hidey,0> <0,trimy,0> 311 }
      texture { texRing }
    }
    //end inner ring

    //five
    prism { bezier_spline hidey, trimy, 29*4,
      tobez(<280,1000>,<280,525>)
      <280,525> <260,510> <250,495> <250,480>
      <250,480> <250,455> <260,445> <280,445>
      <280,445> <300,445> <320,465> <325,490>
      tobez(<325,490>,<480,550>)
      <480,550> <510,520> <550,490> <580,475>
      tobez(<580,475>,<580,145>)
      <580,145> <572,138> <560,133> <550,133>
      <550,133> <540,133> <528,138> <520,145>
      <520,145> <480,180> <440,200> <370,200>
      <370,200> <290,200> <190,120> <190,65>
      <190,65> <190,50> <195,45> <205,45>
      <205,45> <215,45> <230,65> <270,65>
      <270,65> <325,65> <375,40> <420,0>
      <420,0> <490,65> <570,100> <675,100>
      <675,100> <695,100> <710,95> <720,90>
      tobez(<720,90>,<750,100>)
      tobez(<750,100>,<740,180>)
      tobez(<740,180>,<740,490>)
      <740,490> <775,510> <810,550> <810,605>
      tobez(<810,605>,<750,605>)
      <750,605> <720,605> <685,615> <605,680>
      tobez(<605,680>,<460,595>)
      tobez(<460,595>,<325,540>)
      tobez(<325,540>,<325,835>)
      tobez(<325,835>,<665,835>)
      <665,835> <720,835> <775,900> <775,970>
      <775,970> <775,990> <765,1000> <750,1000>
      tobez(<750,1000>,<280,1000>)
      translate <-500,0,-500> scale <0.25,1,0.25>
      texture { texFive }
    }
    //end five

    scale 1/1000
    bounded_by { cylinder { <0,-0.001,0> <0,0.121,0> .53 } }
  }
#end

/**/

#include "colors.inc"
#include "textures.inc"
#include "golds.inc"
#include "stones.inc"

camera {
  direction <0, 0, 1>
  location <0, 1.1, 0.05>
  up <0, 1, 0>
  right <image_width/image_height, 0, 0>
  look_at <0, 0, 0.05>
}
light_source { < 5, 20,  5> color rgb <1.0,1.0,1.0> }
light_source { <-5, 20,  5> color rgb <0.3,0.3,0.3> shadowless }
light_source { < 5, 20, -5> color rgb <0.3,0.3,0.3> shadowless }
light_source { <-5, 20, -5> color rgb <0.3,0.3,0.3> shadowless }

#declare t1 = texture { White_Marble scale 150 rotate <90,0,70> };
#declare t2 = texture { DMFDarkOak translate <0.2,0.3,0> scale 100 rotate <90,60,0> };
#declare t3 = texture { T_Gold_5C scale 100 };
#declare t4 = texture { T_Grnt15 scale 100 rotate <0,60,0>};
#declare t5 = texture { Sapphire_Agate scale 17 rotate <45,0,45> };
object { page51(t1,t2,t3,t4,t5) }

/**/