/* biohazard.pov
 */

#macro biohazard(mTheme,bTheme)
  #local r1 = 1;
  #local r2 = 0.8375;
  #local sp = 0.15;
  merge {
    difference {
      merge {
        #local i=0;
        #while (i<(120*3))
          #local cx = cos(radians(i));
          #local cy = sin(radians(i));
          difference {
            cylinder { <cx/r1,cy/r1,1> <cx/r1,cy/r1,-1> r1 }
            cylinder { <cx/r2,cy/r2,2> <cx/r2,cy/r2,-2> r2-((r1-r2)/10) }
            box { <0,sp/2,2> <0.5,-sp/2,-2> rotate <0,0,i> }
          }
          #local i=i+120;
        #end
      }
      cylinder { <0,0,2> <0,0,-2> 0.225 }
      texture { mTheme }
    }
    union {
      #local i=0;
      #while (i<(120*3))
        #local cx = cos(radians(i))/r2;
        #local cy = sin(radians(i))/r2;
        intersection {
          difference {
            cylinder { <0,0,1> <0,0,-1> 0.825 }
            cylinder { <0,0,2> <0,0,-2> 0.65 }
          }
          cylinder { <cx,cy,2> <cx,cy,-2> r2-sp }
        }
        #local i=i+120;
      #end
      texture { bTheme }
    }
    rotate <0,0,90>
  }
#end

/**/

#include "colors.inc"
#include "stones.inc"

camera {
  direction <0, 0, 1>
  location <0, 0, -5>
  up <0, 1, 0>
  right <image_width/image_height, 0, 0>
  look_at <0, 0, 0>
}
light_source { < 9,  9, -20> color rgb <1.0,1.0,1.0> }
light_source { <-9, -9, -20> color rgb <0.3,0.3,0.3> shadowless }
light_source { < 9, -9, -20> color rgb <0.3,0.3,0.3> shadowless }
light_source { <-9,  9, -20> color rgb <0.3,0.3,0.3> shadowless }

biohazard(texture{T_Stone5 scale .5},texture{T_Stone13 scale .5})

/**/